home *** CD-ROM | disk | FTP | other *** search
/ Aminet 39 / Aminet 39 (2000)(Schatztruhe)[!][Oct 2000].iso / Aminet / dev / basic / PureBasic.lha / PureBasic_1.50_Demo / PureBasic / Examples / Sources / WaponezII.pb < prev    next >
Encoding:
Text File  |  2000-07-19  |  15.2 KB  |  735 lines
  1. ;
  2. ; **************
  3. ;               *
  4. ; Waponez II     **********************************************
  5. ;                                                              *
  6. ;   Origninal Waponez is from NC Gamez ! Check it on Aminet...  *
  7. ;                                                                *
  8. ; *****************************************************************
  9. ;
  10. ;
  11. ; Author note (AlphaSND):
  12. ; -----------------------
  13. ;
  14. ; This game was developped in a hurry (all the game was done in 6 days,
  15. ; working at spare time) so it's just a little example of what the
  16. ; PureBasic can do. This game requiers an AGA Amiga for the nice title
  17. ; screen, else the rest of the gfx are in standard 32 colours (work
  18. ; on all Amiga). 
  19. ;
  20. ; -----------------------------------------------------------------------
  21. ;
  22. ; History:
  23. ;
  24. ; 11/03/2000
  25. ;   + Added sound support !
  26. ;   + Draw a nice title picture...
  27. ;   + Use an AmigaSprite to hide the mouse pointer.
  28. ;   + Commented the code a lot
  29. ;
  30. ; 21/02/2000
  31. ;   + Added Pause & ESC key support :).
  32. ;
  33. ; 20/02/2000
  34. ;   + Added Mapped background... A special tool has been created
  35. ;     to create nice background with ease.
  36. ;   + Start/Stop the sprite server in the loop ensure a good multitask !
  37. ;     Very plaisant to see...
  38. ;   + Added some other aliens (the final boss ;*)
  39. ;   + Added a nice FadeOut routine at the end (easy, it's PB which do it).
  40. ;   + Added collisions between player & sprite.
  41. ;
  42. ; 19/02/2000
  43. ;   + Added real sprite support (still using linked list :*)...)
  44. ;   + Added animated sprite support
  45. ;   + Added lot of bullets... It works very well !! :)
  46. ;   + Added explosion & collision routines.. Need a good CPU now :*D.
  47. ;   + Perfectly smooth on a 1230/50.
  48. ;
  49. ; 18/02/2000
  50. ;   + Added the real gfx, it looks very nice :)
  51. ;   + Implemented the bullets via a linked list, the easier way...
  52. ;
  53. ; 15/02/2000
  54. ;   + Started the routine.
  55. ;   + Very nice looking 50 fps scroll in OS mode.
  56. ;   + Added the main sprite which moving around with joypad...
  57. ;   + Added the aliens :*). 
  58. ;   + Reworked the routine because a big bug (still same speed)
  59. ;
  60.  
  61. ; This game can be started from the Workbench.
  62. ;
  63. WbStartup()
  64.  
  65. ; Initialise all the libraries we're using in this game
  66. ;
  67. InitAmigaSprites(10)
  68. InitSprite(100,100,100)
  69. InitBitMap(2)
  70. InitScreen(2)
  71. InitJoypad()
  72. InitPalette(10)
  73. InitPicture(1)
  74. InitSound(10)
  75. *TagList = InitTagList(100)
  76.  
  77. ;
  78. ; Create and allocate all the necessary bitmaps:
  79. ; 2 for the double buffering routine;
  80. ; 1 for the title screen
  81. ;
  82. AllocateBitMap(0, 320, 480+64+20, 5)  ; 2 x ScreenHeight + 64 + 20 
  83. AllocateBitMap(1, 320, 480+64+20, 5)  ;
  84. AllocateBitMap(2, 320, 50, 8)         ; Title BitMap
  85.  
  86. ;
  87. ; Our own structures for each objects (bullets, aliens,...)
  88. ; It's very handy to use such structures because all the 
  89. ; informations relative to each objects (bullet, aliens,...)
  90. ; like the position, the speed... is stored in the
  91. ; same name. It's object oriented programming :*) (A bit... OOPs)
  92. ;
  93. Structure Bullet
  94.   x.w
  95.   y.w
  96.   Width.w
  97.   Height.w
  98.   Image.w
  99.   SpeedX.w
  100.   SpeedY.w
  101. EndStructure
  102.  
  103. NewList Bullet.Bullet()
  104.  
  105.  
  106. Structure Alien
  107.   x.w
  108.   y.w
  109.   Width.w
  110.   Height.w
  111.   Speed.w
  112.   StartImage.w
  113.   EndImage.w
  114.   ImageDelay.w
  115.   NextImageDelay.w
  116.   ActualImage.w
  117.   Armor.w
  118. EndStructure
  119.  
  120. NewList Aliens.Alien()
  121.  
  122.  
  123. Structure Explosion
  124.   x.w
  125.   y.w
  126.   State.w
  127.   Delay.w
  128. EndStructure
  129.  
  130. NewList Explosion.Explosion()
  131.  
  132.  
  133. ;
  134. ; Now we create the buffers to store the erased background
  135. ; information when we will display the sprites..
  136. ;
  137. UseBitMap(1)
  138. CreateSpriteBuffer(1, 10000, BitMapID())
  139. UseBitMap(0)
  140. CreateSpriteBuffer(0, 10000, BitMapID())
  141.  
  142. ; Our global 'Path$'. All files are relative to this path for easier localisation...
  143. ;
  144. Path$ = "PureBasic:Examples/WaponezII/"
  145.  
  146. LoadSprite(0, Path$+"Back_1")
  147. LoadSprite(1, Path$+"Player_1")
  148. LoadSprite(2, Path$+"Player_2")
  149. LoadSprite(3, Path$+"Player_3")
  150. LoadSprite(4, Path$+"Bullet_1")
  151. LoadSprite(5, Path$+"Back_2")
  152.  
  153. LoadSprite(6, Path$+"Bullet_Right")
  154. LoadSprite(7, Path$+"Bullet_Left")
  155. LoadSprite(8, Path$+"Bullet_Diag1")
  156. LoadSprite(9, Path$+"Bullet_Diag2")
  157.  
  158. LoadSprite(55, Path$+"Bullet_Bottom")
  159.  
  160. ;
  161. ; Sprite 10 to 5 reserved for the rotating animated alien..
  162. ;
  163.  
  164. For k=0 To 5
  165.   LoadSprite(k+10, Path$+"Ennemy_3_"+Str(k+1))
  166. Next
  167.  
  168. ;
  169. ; Sprite 20 to 30 reserved for the explosions...
  170. ;
  171.  
  172. For k=0 To 7
  173.   LoadSprite(k+20, Path$+"Explosion_"+Str(k+1))
  174. Next
  175.  
  176. ;
  177. ; Load all the background blocks...
  178. ;
  179.  
  180. For k=0 to 9
  181.   LoadSprite(k+30, Path$+"Back_"+Str(k+1))
  182. Next
  183.  
  184. LoadSprite(50, Path$+"Boss")
  185.  
  186. ;
  187. ; Load our blank AmigaSprite to hide pointer on the 2 screens
  188. ;
  189.  
  190. LoadAmigaSprite(0, Path$+"Blank")
  191.  
  192. ;
  193. ; Now, load our sounds..
  194. ;
  195.  
  196. SoundPath$ = Path$+"Sounds/"
  197.  
  198. LoadSound(0, SoundPath$+"Lazer")
  199. SetSoundChannels(0, 1)            ; Will be played only the 1st channel
  200. SetSoundVolume(0, 32)
  201.  
  202. LoadSound(1, SoundPath$+"Background")
  203. SetSoundChannels(1, 2)            ; ...only on the 2nd channel
  204.  
  205. LoadSound(2, SoundPath$+"Explosion")
  206. SetSoundChannels(2, 4)            ; ...only the 3nd channel
  207. SetSoundVolume(2, 48)
  208. SetSoundPeriod(2, 400)
  209.  
  210. ;
  211. ; Init all variables with will be used later
  212. ;
  213.  
  214. PlayerWidth  = SpriteWidth(1)
  215. PlayerHeight = SpriteHeight(1)
  216.  
  217. ;
  218. ; Load the needed palette and the title picture (and its palette)
  219. ;
  220. LoadPalette(0, Path$+"Back_1")
  221.  
  222. LoadPicture(0, Path$+"Title_256.iff")  ; Whow a 256 colour picture ?
  223. GetPicturePalette(4, PictureID())      ;
  224.  
  225. UseBitMap(2)                      ; Render the picture on the BitMap
  226. PictureToBitMap(0, BitMapID())    ;
  227.  
  228. ; Very important: change the program priority to 20, as we need lot
  229. ; of cpu time..
  230. ; 
  231. ProgramPriority(20) 
  232.  
  233. ResetTagList(#SA_Type, #CUSTOMSCREEN | #CUSTOMBITMAP)
  234.       AddTag(#SA_Quiet, 1)
  235.       AddTag(#SA_BitMap, BitMapID())
  236. If OpenScreen(1, 320, 25, 8, *TagList)
  237.   DisplayPalette(4,ScreenID())
  238. EndIf
  239.  
  240. UseBitMap(0)
  241. ResetTagList(#SA_Type, #CUSTOMSCREEN | #CUSTOMBITMAP)
  242.       AddTag(#SA_Quiet,1)
  243.       AddTag(#SA_BitMap, BitMapID())
  244.       AddTag(#SA_Top, 28)
  245.       AddTag(#SA_Parent, ScreenID())
  246.       AddTag(#SA_Draggable, 0)
  247. If OpenScreen(0,320,240,5, *TagList)
  248.  
  249.   DisplayPalette(0, ScreenID())
  250.  
  251.   AmigaSpriteScreen(ScreenID())  ; AmigaSprite will be displayed on this screen
  252.  
  253.   AllocateSoundChannels(15) ; All Channels are reserved for Waponez II
  254.  
  255.   PlayerSpeed = 2      ; The speed of our player !
  256.  
  257.   db = 1
  258.    b = 0
  259.  
  260.   ScrollY.w = 240+32+16
  261.  
  262.   AdditionnalBlock = 8
  263.   BackgroundLine   = 0
  264.  
  265.   *Level1 = ?Level1
  266.  
  267.   PlaySound(1,-1)
  268.  
  269.   Repeat
  270.     VWait()
  271.  
  272.     DisplayAmigaSprite(0, 0, 321, 241)    ; remove the mouse pointer ! (Sprite 0 on Channel 0 at position 321, 241)
  273.    
  274.     ShowBitMap(db, ScreenID(), 0, ScrollY) ; Here is the double buffering tips
  275.                                            ; 'db' is alternately 0 and 1 so the bitmaps 0 and 1
  276.                                            ; are displayed one after other. When a bitmap is
  277.                                            ; displayed we do the work on the other bitmap.
  278.  
  279.     StartSpriteServer()    ; Start the sprite server !
  280.  
  281.     Gosub CheckPause
  282.  
  283.     If BackgroundLine < 15*4
  284.       ScrollY-1
  285.  
  286.       If ScrollY<16
  287.         ScrollY = 240+31+16
  288.       EndIf
  289.     Else
  290.       If Boss = 0
  291.         AlienDelay = 100
  292.       EndIf
  293.  
  294.       Boss = 1
  295.     EndIf
  296.  
  297.     db = 1-db
  298.     
  299.     UseSpriteBuffer(db)
  300.     
  301.     ResetSpriteServer()
  302.     RestoreBackGround()
  303.     
  304.     If BackgroundLine < 15*4
  305.     
  306.     BlockY = ScrollY & $FFF0 - 16   ; Little tip to have 16 boundary aligned Y coords..
  307.     
  308.     BlockID1 = PeekB(*Level1)+30     ; Read which blocks should be displayed on the background..
  309.     BlockID2 = PeekB(*Level1+1)+30   ;
  310.     
  311.     AddBlockSprite(BlockID1, BlockX   , BlockY)
  312.     AddBlockSprite(BlockID2, BlockX+16, BlockY)
  313.     AddBlockSprite(BlockID1, BlockX   , BlockY+240+32)
  314.     AddBlockSprite(BlockID2, BlockX+16, BlockY+240+32)
  315.     
  316.     If AdditionnalBlock
  317.       BlockID3 = PeekB(*Level1+2)+30
  318.     
  319.       AddBlockSprite(BlockID3, BlockX+32, BlockY)
  320.       AddBlockSprite(BlockID3, BlockX+32, BlockY+240+32)
  321.     
  322.       AdditionnalBlock-1
  323.       If db = 1
  324.         BlockX+16
  325.         *Level1+1
  326.       EndIf
  327.     EndIf
  328.  
  329.     If db = 1
  330.       BlockX+32
  331.       *Level1+2
  332.     EndIf
  333.  
  334.     If BlockX >= 320
  335.       BlockX = 0
  336.       AdditionnalBlock = 8
  337.       BackgroundLine+1
  338.     Endif
  339.  
  340.     EndIf
  341.  
  342.     UseSpriteBuffer(db)  ; Restore original buffer...
  343.  
  344.     Gosub CheckCollisions
  345.  
  346.     Gosub MovePlayers
  347.     
  348.     Gosub DisplayBullets
  349.     
  350.     Gosub NewAlienWave
  351.     
  352.     Gosub DisplayAliens
  353.     
  354.     Gosub DisplayExplosions
  355.  
  356.     If BulletDelay > 0
  357.       BulletDelay-1
  358.     EndIf
  359.      
  360.     WaitSpriteServer()
  361.     StopSpriteServer()
  362.   Until Quit = 1 OR PressedRawKey() = 69
  363.  
  364.   Gosub EndGame
  365.  
  366. EndIf
  367.  
  368. End
  369.  
  370.                                            
  371. MovePlayers:
  372.  
  373.   Select JoypadMovement(1)
  374.     Case 1
  375.       PlayerY - PlayerSpeed
  376.       PlayerImage = 1
  377.  
  378.     Case 2
  379.       PlayerY - PlayerSpeed
  380.       PlayerX + PlayerSpeed
  381.       PlayerImage = 2
  382.  
  383.     Case 3
  384.       PlayerX + PlayerSpeed
  385.       PlayerImage = 2
  386.  
  387.     Case 4
  388.       PlayerX + PlayerSpeed
  389.       PlayerY + PlayerSpeed
  390.       PlayerImage = 2
  391.  
  392.     Case 5
  393.       PlayerY + PlayerSpeed
  394.       PlayerImage = 1
  395.    
  396.     Case 6
  397.       PlayerY + PlayerSpeed
  398.       PlayerX - PlayerSpeed
  399.       PlayerImage = 3
  400.  
  401.     Case 7
  402.       PlayerX - PlayerSpeed
  403.       PlayerImage = 3
  404.     
  405.     Case 8
  406.       PlayerX - PlayerSpeed
  407.       PlayerY - PlayerSpeed
  408.       PlayerImage = 3
  409.  
  410.     Default
  411.       PlayerImage = 1
  412.  
  413.   EndSelect
  414.  
  415.   If PlayerX < 0 : PlayerX = 0 : EndIf
  416.   If PlayerY < 0 : PlayerY = 0 : EndIf
  417.  
  418.   If PlayerX > 320-PlayerWidth  : PlayerX = 320-PlayerWidth : EndIf
  419.   If PlayerY > 240-PlayerHeight : PlayerY = 240-PlayerHeight : EndIf
  420.  
  421.  
  422.   If Dead = 1 
  423.     AddElement(Explosion())
  424.     Explosion()\x = PlayerX
  425.     Explosion()\y = PlayerY
  426.  
  427.     Dead = 0
  428.   Else
  429.     If DeadDelay>0 
  430.       DeadDelay-1
  431.       If db=1 And DeadDelay < 100
  432.         AddBufferedSprite(PlayerImage, PlayerX, PlayerY+ScrollY)
  433.       EndIf
  434.     Else
  435.       AddBufferedSprite(PlayerImage, PlayerX, PlayerY+ScrollY)
  436.     EndIf
  437.   EndIf
  438.  
  439.   PressedButtons.l = JoypadButtons(1)
  440.   
  441.   
  442.   If PressedButtons & #PB_JOYPAD_BUTTON1
  443.     If BulletDelay = 0 And DeadDelay < 100
  444.     AddElement(Bullet())
  445.     Bullet()\x     = PlayerX+5
  446.     Bullet()\y     = PlayerY-10
  447.     Bullet()\Width = SpriteWidth(4)
  448.     Bullet()\Height= SpriteHeight(4)
  449.     Bullet()\Image = 4
  450.     Bullet()\SpeedY = -7
  451.     BulletDelay = 10
  452.  
  453.     AddElement(Bullet())
  454.     Bullet()\x = PlayerX+26
  455.     Bullet()\y = PlayerY+6
  456.     Bullet()\Width = SpriteWidth(6)
  457.     Bullet()\Height= SpriteHeight(6)
  458.     Bullet()\Image = 6
  459.     Bullet()\SpeedX = 7  
  460.  
  461.     AddElement(Bullet())
  462.     Bullet()\x = PlayerX-11
  463.     Bullet()\y = PlayerY+6
  464.     Bullet()\Width = SpriteWidth(7)
  465.     Bullet()\Height= SpriteHeight(7)
  466.     Bullet()\Image = 7
  467.     Bullet()\SpeedX = -7
  468.  
  469.     AddElement(Bullet())
  470.     Bullet()\x = PlayerX+26
  471.     Bullet()\y = PlayerY-6
  472.     Bullet()\Width = SpriteWidth(8)
  473.     Bullet()\Height= SpriteHeight(8)
  474.     Bullet()\Image = 8
  475.     Bullet()\SpeedX = 7
  476.     Bullet()\SpeedY = -7
  477.  
  478.     AddElement(Bullet())
  479.     Bullet()\x = PlayerX-11
  480.     Bullet()\y = PlayerY-6
  481.     Bullet()\Width = SpriteWidth(9)
  482.     Bullet()\Height= SpriteHeight(9)
  483.     Bullet()\Image = 9
  484.     Bullet()\SpeedX = -7
  485.     Bullet()\SpeedY = -7
  486.  
  487.     AddElement(Bullet())
  488.     Bullet()\x = PlayerX+12
  489.     Bullet()\y = PlayerY+32
  490.     Bullet()\Width = SpriteWidth(55)
  491.     Bullet()\Height= SpriteHeight(55)
  492.     Bullet()\Image = 55
  493.     Bullet()\SpeedY = 7
  494.  
  495.     PlaySound(0,1)
  496.  
  497.     EndIf
  498.   EndIf
  499.  
  500.   P2.l = JoypadButtons(0)
  501.  
  502.   If P2 & #PB_JOYPAD_BUTTON2
  503.     Quit = 1
  504.   EndIf
  505.  
  506. Return
  507.  
  508.  
  509. NewAlienWave:
  510.  
  511.   If AlienDelay = 0
  512.  
  513.     AddElement(Aliens())
  514.  
  515.     If Boss = 1
  516.       Aliens()\x = 100
  517.       Aliens()\y = -16
  518.       Aliens()\Width  = SpriteWidth(50)
  519.       Aliens()\Height = SpriteHeight(50)
  520.       Aliens()\Speed  = 2
  521.       Aliens()\StartImage = 50
  522.       Aliens()\EndImage = 50
  523.       Aliens()\ImageDelay = 1
  524.       Aliens()\NextImageDelay = 1
  525.       Aliens()\ActualImage = 50
  526.       Aliens()\Armor = 20
  527.    
  528.       AlienDelay = 80
  529.  
  530.     Else
  531.  
  532.     Aliens()\x = 100
  533.     Aliens()\y = -16
  534.     Aliens()\Width  = SpriteWidth(10) 
  535.     Aliens()\Height = SpriteHeight(10)
  536.     Aliens()\Speed = 2
  537.     Aliens()\StartImage  = 10 
  538.     Aliens()\EndImage    = 15 
  539.     Aliens()\ImageDelay  =  4
  540.     Aliens()\NextImageDelay = Aliens()\ImageDelay
  541.     Aliens()\ActualImage = 10
  542.     Aliens()\Armor = 4
  543.  
  544.     AlienDelay = 22
  545.  
  546.     Endif
  547.   Else
  548.     AlienDelay - 1
  549.   EndIf
  550.  
  551. Return
  552.  
  553.  
  554. DisplayAliens:
  555.  
  556.   ResetList(Aliens())
  557.   While NextElement(Aliens())
  558.  
  559.     AddBufferedSprite(Aliens()\ActualImage, Aliens()\x, Aliens()\y+ScrollY)
  560.  
  561.     Aliens()\y + Aliens()\Speed
  562.  
  563.     If Aliens()\NextImageDelay = 0
  564.  
  565.       Aliens()\ActualImage+1
  566.  
  567.       If Aliens()\ActualImage > Aliens()\EndImage
  568.         Aliens()\ActualImage = Aliens()\StartImage
  569.       EndIf
  570.  
  571.       Aliens()\NextImageDelay = Aliens()\ImageDelay
  572.     Else
  573.       Aliens()\NextImageDelay-1
  574.     EndIf
  575.  
  576.     If Aliens()\Armor <= 0 Or Aliens()\y > 240+16
  577.       If Aliens()\Armor <= 0
  578.  
  579.         AddElement(Explosion())
  580.         Explosion()\x = Aliens()\x
  581.         Explosion()\y = Aliens()\y
  582.  
  583.         Score+20
  584.       EndIf
  585.  
  586.       KillElement(Aliens())
  587.     EndIf
  588.   Wend
  589. Return
  590.  
  591.  
  592. DisplayBullets:
  593.  
  594.   ResetList(Bullet())
  595.   While NextElement(Bullet())
  596.  
  597.     If Bullet()\y < 0
  598.       KillElement(Bullet())
  599.     Else
  600.       If Bullet()\x < 0
  601.         KillElement(Bullet())
  602.       Else
  603.  
  604.         If Bullet()\x > 320-Bullet()\Width
  605.           KillElement(Bullet())
  606.         Else
  607.           If Bullet()\y > 245
  608.             KillElement(Bullet())
  609.           Else
  610.             AddBufferedSprite(Bullet()\Image, Bullet()\x, Bullet()\y+ScrollY)
  611.  
  612.             Bullet()\y + Bullet()\SpeedY
  613.             Bullet()\x + Bullet()\SpeedX
  614.           Endif
  615.         EndIf
  616.       EndIf
  617.     EndIf
  618.  
  619.   Wend
  620.  
  621. Return
  622.  
  623. ;
  624. ; This routine is very CPU intensive when many bullets are flying
  625. ; all around the screen...
  626. ;
  627. CheckCollisions:
  628.  
  629.   ResetList(Aliens())
  630.   While NextElement(Aliens())
  631.     ResetList(Bullet())
  632.     While NextElement(Bullet())
  633.  
  634.       If Bullet()\y <= Aliens()\y+Aliens()\Height
  635.         If Bullet()\y+Bullet()\Height >= Aliens()\y
  636.           If Bullet()\x+Bullet()\Width => Aliens()\x
  637.             If Bullet()\x <= Aliens()\x+Aliens()\Width
  638.               Aliens()\Armor-1
  639.               KillElement(Bullet())
  640.             EndIf
  641.           EndIf
  642.         EndIf
  643.       EndIf
  644.     Wend
  645.  
  646.     If DeadDelay = 0
  647.     If PlayerX+PlayerWidth > Aliens()\x
  648.       If PlayerX < Aliens()\x+Aliens()\Width
  649.         If PlayerY+PlayerHeight > Aliens()\y
  650.           If PlayerY < Aliens()\y+Aliens()\Height
  651.             Dead = 1
  652.             DeadDelay = 180 
  653.  
  654.             AddElement(Explosion())
  655.             Explosion()\x = Aliens()\x
  656.             Explosion()\y = Aliens()\y
  657.  
  658.             KillElement(Aliens())
  659.           EndIf
  660.         EndIf
  661.       EndIf
  662.     EndIf
  663.     EndIf
  664.   Wend
  665.  
  666. Return
  667.  
  668.  
  669. DisplayExplosions:
  670.  
  671.   ResetList(Explosion())
  672.   While NextElement(Explosion())
  673.  
  674.     AddBufferedSprite(Explosion()\State+20, Explosion()\x, Explosion()\y+ScrollY)
  675.  
  676.     If Explosion()\Delay = 0
  677.       If Explosion()\State = 0
  678.         PlaySound(2,1) 
  679.       EndIf
  680.  
  681.       If Explosion()\State < 7
  682.         Explosion()\State+1
  683.         Explosion()\Delay = 2
  684.       Else
  685.         KillElement(Explosion())
  686.       Endif
  687.     Else
  688.       Explosion()\Delay-1
  689.     EndIf
  690.   Wend
  691.  
  692. Return
  693.  
  694.  
  695. CheckPause:
  696.  
  697.   If PressedRawKey() = 25
  698.  
  699.     WaitSpriteServer()
  700.     StopSpriteServer()
  701.  
  702.     StopSound(0)
  703.  
  704.     Repeat
  705.       VWait()
  706.     Until PressedRawKey() <> 25
  707.  
  708.     Repeat
  709.       VWait()
  710.     Until PressedRawKey() = 25
  711.  
  712.     Repeat
  713.       VWait()
  714.     Until PressedRawKey() <> 25
  715.  
  716.     PlaySound(1,-1)
  717.  
  718.     StartSpriteServer()
  719.  
  720.   EndIf
  721. Return
  722.  
  723.  
  724. EndGame:
  725.  
  726.   FadeOut(0, ScreenID(), 4, 64)
  727.  
  728.   HideScreen()
  729.  
  730. Return
  731.  
  732.  
  733. Level1:
  734. IncludeBinary "PureBasic:Examples/WaponezII/DefaultMap"
  735.